# set term postscript eps color solid blacktext "Helvetica" 14

# set output 'loradtn.eps'

# set size 4,4

set terminal png nocrop enhanced size 1024,768

set output 'loradtn-2017-02-08.png'

set datafile separator ","

set xdata time

set timefmt "%Y-%m-%d %H:%M:%S"

os='2017-02-08 11:00:00'

oe='2017-02-08 16:00:00'

#os='2017-01-24 14:00:00'

#oe='2017-01-25 13:00:00'

set title "Loradtn power (Mech. Eng. roof)"

set key below 

r1=1700

r2=1800

r3=1900

r4=2000

nospike=0

spike=1

newdata=2

set xrange [os:oe]

set yrange [1500:19000]

set y2range [-6000:8000]

set ylabel "mV"

set y2label "mA"

set ytics nomirror

set ytics (\

"OVERRIDE" 5000,\

"UP" 4500,\

"STBYSHORT" 4000,\

"STBYLONG" 3500,\

"SLEEP" 3000,\

"OFF" 2500,\

"14500" 14500,\

"14000" 14000,\

"13500" 13500,\

"13000" 13000,\

"12500" 12500,\

"12000" 12000,\

"11500" 11500,\

"11000" 11000,\

"spike" 10050)

set y2tics ( 4000, 3500, 3000, 2500, 2000, 1500, 1000, 500, 0, -500, -1000, "spike" -2000 )

set style arrow 1 nohead ls 1 lt 3

set style arrow 2 nohead ls 2

set style arrow 3 nohead lc rgb "green"

set style arrow 4 nohead lc rgb "red"

# some horizontal lines to help

set arrow from os,12000 to oe,12000 as 1

set arrow from os,11450 to oe,11450 as 3

set arrow from os,11300 to oe,11300 as 4

set arrow from os,second 1000 to oe,second 1000 as 2

set arrow from os,second 0 to oe,second 0 as 2

set arrow from os,second -1000 to oe,second -1000 as 2

set pointsize 10

plot 'sedded-battery.log' using 1: ( ($2 == r1 && $7 != newdata) ? ( ( ($7 == spike) ? 10050 : (10 * $4) ) ) : 1/0 ) axes x1y1 title "mV" with points ps 1, \

     'sedded-battery.log' using 1: ( ($2 == r1 && $7 != newdata) ? ( ( ($7 == spike) ?   -2000 :       $5  ) ) : 1/0 ) axes x1y2 title "mA" with points ps 1, \

     'sedded-battery.log' using 1: ( ($2 == r1) ? (2000 + $6) : 1/0 ) axes x1y1 title "state" with step